-
Notifications
You must be signed in to change notification settings - Fork 1
/
gilded_rose.ex
77 lines (58 loc) · 2 KB
/
gilded_rose.ex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
defmodule Item do
defstruct name: nil, sell_in: nil, quality: nil
end
defmodule GildedRose do
# Example
# update_quality([%Item{name: "Backstage passes to a TAFKAL80ETC concert", sell_in: 9, quality: 1}])
# => [%Item{name: "Backstage passes to a TAFKAL80ETC concert", sell_in: 8, quality: 3}]
@backstage "Backstage passes to a TAFKAL80ETC concert"
def update_quality(items) do
Enum.map(items, &update_item/1)
end
def update_item(%Item{name: "Aged Brie", sell_in: sell_in} = item) when sell_in <= 0 do
item |> age() |> improve(2)
end
def update_item(%Item{name: "Aged Brie"} = item) do
item |> age() |> improve(1)
end
def update_item(%Item{name: "Sulfuras, Hand of Ragnaros"} = item) do
item |> quality(80)
end
def update_item(%Item{name: @backstage, sell_in: sell_in} = item) when sell_in <= 0 do
item |> age() |> quality(0)
end
def update_item(%Item{name: @backstage, sell_in: sell_in} = item) when sell_in <= 5 do
item |> age() |> improve(3)
end
def update_item(%Item{name: @backstage, sell_in: sell_in} = item) when sell_in <= 10 do
item |> age() |> improve(2)
end
def update_item(%Item{name: @backstage} = item) do
item |> age() |> improve(1)
end
def update_item(%Item{name: "Conjured Mana Cake", sell_in: sell_in} = item) when sell_in <= 0 do
item |> age() |> degrade(4)
end
def update_item(%Item{name: "Conjured Mana Cake"} = item) do
item |> age() |> degrade(2)
end
def update_item(%Item{sell_in: sell_in} = item) when sell_in <= 0 do
item |> age() |> degrade(2)
end
def update_item(%Item{} = item) do
item |> age() |> degrade(1)
end
# Helpers
defp age(%Item{} = item) do
%Item{item | sell_in: item.sell_in - 1}
end
defp degrade(%Item{} = item, rate) do
%Item{item | quality: max(item.quality - rate, 0)}
end
defp improve(%Item{} = item, rate) do
%Item{item | quality: min(item.quality + rate, 50)}
end
defp quality(%Item{} = item, quality) do
%Item{item | quality: quality}
end
end