build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {

    // version variables
    ext.versions = [
            kotlin        : '1.2.71',
            minSdk        : 14,
            compileSdk    : 27,
            buildTools    : '28.0.3',
            supportLibrary: '27.0.2',
    ]

    ext.deps = [
            kotlin     : [
                    stdlib : "org.jetbrains.kotlin:kotlin-stdlib-jdk8:${versions.kotlin}",
                    reflect: "org.jetbrains.kotlin:kotlin-reflect:${versions.kotlin}"
            ],
            android    : [
                    runtime: 'com.google.android:android:4.1.1.4',
                    plugin : 'com.android.tools.build:gradle:3.2.0',
                    runner : 'androidx.test:runner:1.1.0',
                    rules  : 'androidx.test:rules:1.1.0',
                    junit  : 'androidx.test.ext:junit:1.0.0'
            ],
            support    : [
                    annotations: "com.android.support:support-annotations:${versions.supportLibrary}",
                    fragment   : "com.android.support:support-fragment:${versions.supportLibrary}"
            ],
            auto       : [
                    service: 'com.google.auto.service:auto-service:1.0-rc4'
            ],
            tutuur     : [
                    'compilerutil': "com.tutuur.android:compiler-util:0.9.16",
                    'annotation'  : "com.tutuur.android:navigator-annotation:${VERSION_NAME}",
                    'compiler'    : "com.tutuur.android:navigator-compiler:${VERSION_NAME}",
                    'const'       : "com.tutuur.android:navigator-const:${VERSION_NAME}",
                    'navigator'   : "com.tutuur.android:navigator:${VERSION_NAME}",
            ],
            guava      : 'com.google.guava:guava:24.0-jre',
            javapoet   : 'com.squareup:javapoet:1.11.1',
            junit      : 'junit:junit:4.12',
            truth      : 'com.google.truth:truth:0.42',
            robolectric: 'org.robolectric:robolectric:3.7.1',
    ]

    repositories {
        google()
        jcenter()
    }

    dependencies {
        classpath deps.android.plugin
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:${versions.kotlin}"
        classpath "com.tutuur.android:navigator-plugin:${VERSION_NAME}"
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

subprojects { project ->

    group = GROUP
    version = VERSION_NAME

    repositories {
        google()
        jcenter()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}