Idiomatic negation / set difference

[nasser]

what's the most idiomatic way to approach negation in metta? I am particularly interested it in the context of composite queries where i have a sense of how to construct a logical AND with nested matches

(friend bob larry)
(friend bob mike)

(teacher bob)
(capenter larry)
(doctor mike)

;; friend of bob AND a carpenter
! (match &self (friend bob $f) (match &self (capenter $f) $f))
;; [larry]

but it is less clear how to express negation, i.e. "friends of bob AND-NOT carpenter" which i would expect to produce [mike] given the above assertions.

relatedly I have a sense of how to model the set-theoretic intersection of two nondeterministic results

(= (intersect $a $b)
    (let* ( ($aa $a)
            ($bb $b))
        (unify ($aa $bb) ($x $x) $x (empty))))

(mammal dog)
(mammal cat)
(mammal tiger)
(bird parrot)
(bird vulture)
(pet dog)
(pet cat)
(pet parrot)

; all mammals that are pets
! (intersect (match &self (mammal $m) $m) (match &self (pet $p) $p))
;; [dog, cat]

; all birds that are pets
! (intersect (match &self (bird $m) $m) (match &self (pet $p) $p))
;; [parrot]

but it is not clear how to model set-theoretic difference, e.g. "all mammals that ARE-NOT" pets.

what's the best practice here?

[vsbogd]

@nasser , thank you for the question. Simple manual way of doing it is nesting unify with alternatives. For two examples above it is:

;; friend of bob AND NOT a carpenter
! (unify &self (friend bob $f)
   (unify &self (capenter $f) ; $f is a friend of Bob
     (empty) ; $f is a carpenter
     $f) ; $f is not a carpenter
   (empty)) ; $f is a friend of Bob

;; all mammals that ARE NOT pets
! (unify &self (mammal $m)
   (unify &self (pet $m) ; $m is a mammal
     (empty) ; $m is a pet
     $m) ; $m is not a pet
   (empty)) ; $m is not a mammal

Thus in general NOT <query> can be implemented using (unify <space> <query> (empty) <if-not-result>).

[vsbogd]

OR or union query can be represented using superpose:

!(superpose (
   (unify &self (mammal $m) $m (empty))
   (unify &self (bird $b) $b (empty))
))
; [tiger, cat, dog, vulture, parrot]

[vsbogd]

The examples I provided are AND NOT examples. To implement just NOT something instead of AND NOT something you can get the full set of results first:

!(unify &self ($p $s) (unify &self (pet $s) (empty) $s) (empty)) ; returns anything except pets

[nasser]

Very helpful -- thank you!

[Necr0x0Der]

JIC, @nasser , do you prefer pure match / unify queries or a more logical form?