build.gradle

/*
    Gradle root build file
    Project: HomeSetup
    Created: 5th March, 2022
    Copyright (c) 2024, HomeSetup team
*/

plugins {
  id 'idea'
  id "org.jetbrains.gradle.plugin.idea-ext" version "1.1.7"
}

idea {
  module {
    settings {
      rootModuleType = 'PYTHON_MODULE'
    }
    sourceDirs += file('bin')
    sourceDirs += file('dotfiles')
    testSourceDirs += file('tests')
    excludeDirs += file('.idea')
    excludeDirs += file('.gradle')
    excludeDirs += file('.vscode')
    excludeDirs += file('run-configs')
  }
}

tasks.withType(Exec) {
  doFirst {
    println commandLine
  }
}

String detectPython() {
  def pythonHome = System.getenv('PYTHON_HOME') ?: null
  if (pythonHome != null) {
      return pythonHome + '/python3'
  }

  def output = new ByteArrayOutputStream()
  exec {
      commandLine 'bash', '-c', 'command -v python3'
      standardOutput = output
  }

  pythonHome = output.toString().trim()
  assert pythonHome != null && !pythonHome.isEmpty(), "Could not find any installed python3 version"

  return pythonHome
}

ext {
  bash = "bash${bashVersion}"
  versionFile = "$rootDir/.VERSION"
  verbose = findProperty('verbose') ?: false
  python = detectPython()
}

apply from: "$projectDir/gradle.properties"
apply from: "$projectDir/gradle/versioning.gradle"
apply from: "$projectDir/gradle/bash.gradle"
apply from: "$projectDir/gradle/idea.gradle"