build.gradle

plugins {
    id "java-library"
}

group = 'com.zebrunner'
version = "${version != 'unspecified' ? version : '1.0-SNAPSHOT'}"

ext.coreVersion = project.properties['core.version'] ?: '1.0-SNAPSHOT'

repositories {
    mavenCentral()
    maven {
        url "https://oss.sonatype.org/content/repositories/snapshots/"
    }
    maven {
        url "https://nexus.zebrunner.dev/repository/ce-snapshots/"
    }
}

dependencies {
    implementation("com.google.code.gson:gson:2.10.1")

    api("com.zebrunner:agent-core:${coreVersion}")
    implementation("com.nordstrom.tools:junit-foundation:17.0.3")
    implementation("junit:junit:4.13.2")

    annotationProcessor("org.projectlombok:lombok:1.18.26")
    compileOnly("org.projectlombok:lombok:1.18.26")
}

jar {
    manifest {
        attributes(
                "Premain-Class": "com.zebrunner.agent.junit.JUnitAgent",
                "Can-Redefine-Classes": false,
                "Can-Retransform-Classes": true,
                "Build-Jdk": "1.8.0_152"
        )
    }
}

apply from: 'publish-maven.gradle'