Merge pull request #302483 from r-ryantm/auto-update/tegola

tegola: 0.19.0 -> 0.20.0

pkgs/by-name/te/tegola/package.nix

@@ -0,0 +1,48 @@
+{ lib, buildGoModule, buildNpmPackage, fetchFromGitHub }:
+let
+  version = "0.20.0";
+
+  src = fetchFromGitHub {
+    owner = "go-spatial";
+    repo = "tegola";
+    rev = "v${version}";
+    sha256 = "sha256-Jlpw3JaU5+DO7Z5qruEMoLRf95cPGd9Z+MeDGSgbMjc=";
+  };
+
+  frontend = buildNpmPackage {
+    pname = "tegola-ui";
+    inherit version;
+
+    src = "${src}/ui";
+
+    npmDepsHash = "sha256-rhUdWt1X5/F0uvT8gI1T9ei6Y+HK1tKj2fuTKlMAwJk=";
+
+    installPhase = ''
+      cp -r dist $out
+    '';
+  };
+in
+buildGoModule {
+  pname = "tegola";
+  inherit version src;
+
+  vendorHash = null;
+
+  subPackages = [ "cmd/tegola" ];
+
+  ldflags = [ "-s" "-w" "-X github.com/go-spatial/tegola/internal/build.Version=${version}" ];
+
+  preBuild = ''
+    rm -rf ui/dist
+    cp -r ${frontend} ui/dist
+    go generate ./server
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.tegola.io/";
+    description = "Mapbox Vector Tile server";
+    mainProgram = "tegola";
+    maintainers = with maintainers; teams.geospatial.members ++ [ ingenieroariel ];
+    license = licenses.mit;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -27042,8 +27042,6 @@ with pkgs;
 
   pg_tileserv = callPackage ../servers/geospatial/pg_tileserv { };
 
-  tegola = callPackage ../servers/geospatial/tegola { };
-
   tile38 = callPackage ../servers/geospatial/tile38 { };
 
   ### OS-SPECIFIC