Add multiple-receive bbe

examples/index.json

@@ -1475,6 +1475,13 @@
         "verifyOutput": true,
         "isLearnByExample": true
       },
+      {
+        "name": "Multiple receive",
+        "url": "multiple-receive",
+        "verifyBuild": true,
+        "verifyOutput": true,
+        "isLearnByExample": true
+      },
       {
         "name": "Conditional send",
         "url": "conditional-send",

examples/multiple-receive/multiple_receive.bal

@@ -0,0 +1,36 @@
+import ballerina/http;
+import ballerina/io;
+import ballerina/lang.runtime;
+
+type Response record {
+    record {
+        string 'worker;
+    } args;
+};
+
+type Result record {
+    string|error a;
+    string|error b;
+};
+
+function fetch(string workerParam) returns string|error {
+    http:Client cl = check new ("https://postman-echo.com");
+    Response response = check cl->/get('worker = workerParam);
+    return response.args.'worker;
+}
+
+public function main() {
+    // Workers `w1` and `w2` fetch content using the respective arguments.
+    worker w1 {
+        fetch("w1") -> function;
+    }
+
+    worker w2 {
+        runtime:sleep(2);
+        fetch("w2") -> function;
+    }
+
+    // The worker waits until both values are received.
+    Result result = <- {a: w1, b: w2};
+    io:println(result);
+}

examples/multiple-receive/multiple_receive.md

@@ -0,0 +1,7 @@
+# Multiple receive
+
+The multiple receive action can be used to receive values corresponding to multiple send actions. It operates by waiting for the receipt of values from all the send actions, subsequently constructing a mapping value containing those values.
+
+::: code multiple_receive.bal :::
+
+::: out multiple_receive.out :::

examples/multiple-receive/multiple_receive.metatags

@@ -0,0 +1,2 @@
+description: This BBE demonstrates the use of the multiple receive action in inter-worker communication
+keywords: ballerina, ballerina by example, bbe, worker, multiple receive

examples/multiple-receive/multiple_receive.out

@@ -0,0 +1,2 @@
+$ bal run multiple_receive.bal
+{"a":"w1","b":"w2"}