build: Move to publishing with gradle

README.md

@@ -1,4 +1,10 @@
 # Box2DLights
+
+[![GitHub Actions Build Status](https://img.shields.io/github/actions/workflow/status/libgdx/box2dlights/gradle.yml?branch=master&label=GitHub%20Actions)](https://github.com/libgdx/libgdx/actions?query=workflow%3A%22Build+and+Publish%22)
+
+[![Latest Version](https://img.shields.io/nexus/r/com.badlogicgames.box2dlights/box2dlights?nexusVersion=2&server=https%3A%2F%2Foss.sonatype.org&label=Version)](https://search.maven.org/artifact/com.badlogicgames.box2dlights/box2dlights)
+[![Snapshots](https://img.shields.io/nexus/s/com.badlogicgames.box2dlights/box2dlights?server=https%3A%2F%2Foss.sonatype.org&label=Snapshots)](https://oss.sonatype.org/#nexus-search;gav~com.badlogicgames.box2dlights~box2dlights~~~~kw,versionexpand)
+
 [![screenshot](http://img.youtube.com/vi/lfT8ajGbzk0/0.jpg)](http://www.youtube.com/watch?v=lfT8ajGbzk0)
 
 Kalle Hameleinen's Box2DLights is a 2D lighting framework that uses [box2d](http://box2d.org/) for raycasting and OpenGL ES 2.0 for rendering. This library is intended to be used with [libgdx](http://libgdx.com).

build.gradle

@@ -7,6 +7,9 @@ sourceSets {
 		java {
 			srcDirs = ["src"]
 		}
+		resources {
+			srcDirs = ["res"]
+		}
 	}
 	test {
 		java {
@@ -15,17 +18,61 @@ sourceSets {
 	}
 }
 
-ext.gdxVersion = "1.9.11"
-version = "1.6-SNAPSHOT"
+ext {
+	gdxVersion = "1.9.11"
+
+	isReleaseBuild = {
+		return project.hasProperty("RELEASE")
+	}
+
+	getReleaseRepositoryUrl = {
+		return project.hasProperty('RELEASE_REPOSITORY_URL') ? RELEASE_REPOSITORY_URL
+				: "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
+	}
+
+	getSnapshotRepositoryUrl = {
+		return project.hasProperty('SNAPSHOT_REPOSITORY_URL') ? SNAPSHOT_REPOSITORY_URL
+				: "https://oss.sonatype.org/content/repositories/snapshots/"
+	}
+
+	getRepositoryUsername = {
+		return project.hasProperty('NEXUS_USERNAME') ? NEXUS_USERNAME : ""
+	}
+
+	getRepositoryPassword = {
+		return project.hasProperty('NEXUS_PASSWORD') ? NEXUS_PASSWORD : ""
+	}
+}
+
+version project.getProperty('version') + (isReleaseBuild() ? "" : "-SNAPSHOT")
+
+java {
+	sourceCompatibility = 1.7
+	targetCompatibility = 1.7
+
+	withJavadocJar()
+	withSourcesJar()
+}
 
 repositories {
+	mavenLocal()
 	mavenCentral()
 }
 
+tasks.withType(JavaCompile).configureEach {
+	options.encoding = 'UTF-8'
+}
+
+tasks.withType(Test).configureEach {
+	systemProperty 'file.encoding', 'UTF-8'
+}
+
 dependencies {
 	implementation "com.badlogicgames.gdx:gdx:$gdxVersion"
 	implementation "com.badlogicgames.gdx:gdx-box2d:$gdxVersion"
 	testImplementation "com.badlogicgames.gdx:gdx-box2d-platform:$gdxVersion:natives-desktop"
 	testImplementation "com.badlogicgames.gdx:gdx-backend-lwjgl:$gdxVersion"
 	testImplementation "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
-}
+}
+
+apply from: rootProject.file('publish.gradle')

gradle.properties

@@ -0,0 +1,12 @@
+group=com.badlogicgames.box2dlights
+version=1.6
+POM_DESCRIPTION=2D real-time lighting using box2d
+POM_NAME=Box2dlights
+POM_URL=https://github.com/libgdx/box2dlights
+POM_ISSUE_URL=https://github.com/libgdx/box2dlights/issues
+POM_SCM_URL=https://github.com/libgdx/box2dlights
+POM_SCM_CONNECTION=scm:git:https://github.com/libgdx/box2dlights.git
+POM_SCM_DEV_CONNECTION=scm:git:https://github.com/libgdx/box2dlights.git
+POM_LICENCE_NAME=Apache Licence 2.0
+POM_LICENCE_URL=https://www.apache.org/licenses/LICENSE-2.0
+POM_LICENCE_DIST=repo

publish.gradle

@@ -0,0 +1,72 @@
+apply plugin: 'maven-publish'
+apply plugin: 'signing'
+
+publishing {
+    publications {
+        mavenJava(MavenPublication) {
+            from components.java
+            versionMapping {
+                usage('java-api') {
+                    fromResolutionOf('runtimeClasspath')
+                }
+                usage('java-runtime') {
+                    fromResolutionResult()
+                }
+            }
+            pom {
+                name = POM_NAME
+                description = POM_DESCRIPTION
+                url = POM_URL
+                issueManagement {
+                    url = POM_ISSUE_URL
+                }
+                licenses {
+                    license {
+                        name = POM_LICENCE_NAME
+                        url = POM_LICENCE_URL
+                        distribution = POM_LICENCE_DIST
+                    }
+                }
+                developers {
+                    developer {
+                        id = "Developers"
+                        url = "https://github.com/libgdx/box2dlights/graphs/contributors"
+                    }
+                }
+                scm {
+                    connection = POM_SCM_CONNECTION
+                    developerConnection = POM_SCM_DEV_CONNECTION
+                    url = POM_SCM_URL
+                }
+            }
+        }
+    }
+
+    repositories {
+        maven {
+            url = version.endsWith('SNAPSHOT') ? getSnapshotRepositoryUrl() : getReleaseRepositoryUrl()
+
+            if (getRepositoryUsername() || getRepositoryPassword())
+            {
+                credentials {
+                    username = getRepositoryUsername()
+                    password = getRepositoryPassword()
+                }
+            }
+        }
+    }
+}
+
+signing {
+    useGpgCmd()
+    sign publishing.publications.mavenJava
+}
+
+//Simply using "required" in signing block doesn't work because taskGraph isn't ready yet.
+gradle.taskGraph.whenReady {
+    tasks.withType(Sign).tap {
+        configureEach {
+            onlyIf { isReleaseBuild() }
+        }
+    }
+}