Vectorized hash grouping by a single text column

.unreleased/vectorized-text-grouping

@@ -0,0 +1 @@
+Implements: #7586 Vectorized aggregation with grouping by a single text column.

scripts/clang_format_all.sh

@@ -5,5 +5,5 @@ SCRIPT_DIR=$(cd "$(dirname $0)" || exit; pwd)
 BASE_DIR=$(dirname $SCRIPT_DIR)
 
 find ${BASE_DIR} \( -path "${BASE_DIR}/src/*" -or -path "${BASE_DIR}/test/*" -or -path "${BASE_DIR}/tsl/*" \) \
-    -and -not \( -path "*/.*" -or -path "*CMake*" \) \
+    -and -not \( -path "*/.*" -or -path "*CMake*" -or -path "${BASE_DIR}/tsl/src/import/*" \) \
     -and \( -name '*.c' -or -name '*.h' \) -print0 | xargs -0 ${SCRIPT_DIR}/clang_format_wrapper.sh -style=file -i

tsl/CMakeLists.txt

@@ -4,5 +4,55 @@ if(COMPRESSION_FUZZING)
   add_compile_definitions(TS_COMPRESSION_FUZZING=1)
 endif()
 
+# Check whether we can enable the pclmul instruction required for the UMASH
+# hashing on amd64. Shouldn't be done if the user has manually specified the
+# target architecture, no idea how to detect this, but at least we shouldn't do
+# this when cross-compiling.
+if(NOT CMAKE_CROSSCOMPILING)
+  check_c_compiler_flag(-mpclmul CC_PCLMUL)
+  if(CC_PCLMUL)
+    add_compile_options(-mpclmul)
+    # The "C source compiles" check below doesn't use the global compilation
+    # flags, so we have to modify its flags separately.
+    set(CMAKE_REQUIRED_FLAGS -mpclmul)
+  endif()
+endif()
+
+# Detect if we can compile UMASH on this platform. It is not tested on Windows
+# and leads to a weird CI freeze, so don't even try for now.
+if(NOT WIN32)
+  set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)
+  check_c_source_compiles(
+    "
+#if defined(__PCLMUL__)
+#include <stdint.h>
+#include <immintrin.h>
+/*
+ * For some reason, this doesn't compile on our i386 CI, but I also can't detect
+ * it using the standard condition of defined(__x86_64__) && !defined(__ILP32__),
+ * as described at https://wiki.debian.org/X32Port .
+ */
+void test() { (void) _mm_cvtsi64_si128((uint64_t) 0); }
+#elif defined(__ARM_FEATURE_CRYPTO)
+#else
+#error Unsupported platform for UMASH
+#endif
+"
+    UMASH_SUPPORTED)
+  unset(CMAKE_REQUIRED_FLAGS)
+  unset(CMAKE_TRY_COMPILE_TARGET_TYPE)
+else()
+  set(UMASH_SUPPORTED CACHE OFF)
+endif()
+
+option(USE_UMASH
+       "Use the UMASH hash for string and multi-column vectorized grouping"
+       ${UMASH_SUPPORTED})
+
+if(USE_UMASH)
+  add_compile_definitions(TS_USE_UMASH)
+endif()
+
+# Add the subdirectories
 add_subdirectory(test)
 add_subdirectory(src)

tsl/src/import/CMakeLists.txt

@@ -1,2 +1,15 @@
-set(SOURCES "")
-target_sources(${PROJECT_NAME} PRIVATE ${SOURCES})
+set(SOURCES)
+
+if(USE_UMASH)
+  list(APPEND SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/umash.c)
+endif()
+
+if(SOURCES)
+  # Disable clang-tidy for imported code
+  add_library(target_no_static_code_analysis OBJECT ${SOURCES})
+  set_target_properties(target_no_static_code_analysis PROPERTIES C_CLANG_TIDY
+                                                                  "")
+
+  target_link_libraries(${TSL_LIBRARY_NAME}
+                        $<TARGET_OBJECTS:target_no_static_code_analysis>)
+endif()