Added nix support

default.nix

@@ -0,0 +1,56 @@
+# An example package with dependencies defined via pyproject.toml
+{
+  config,
+  lib,
+  dream2nix,
+  ...
+}: let
+  pyproject = lib.importTOML (config.mkDerivation.src + /pyproject.toml);
+in {
+  imports = [
+    dream2nix.modules.dream2nix.pip
+  ];
+
+  deps = {nixpkgs, ...}: {
+    python = nixpkgs.python3;
+    hatch = nixpkgs.hatch;
+    hatchling = nixpkgs.python3.pkgs.hatchling;
+  };
+
+  inherit (pyproject.project) name version;
+
+  mkDerivation = {
+    src = lib.cleanSourceWith {
+      src = lib.cleanSource ./.;
+      filter = name: type:
+        !(builtins.any (x: x) [
+          (lib.hasSuffix ".nix" name)
+          (lib.hasPrefix "." (builtins.baseNameOf name))
+          (lib.hasSuffix "flake.lock" name)
+        ]);
+    };
+  };
+
+  buildPythonPackage = {
+    pyproject = true;
+    build-system = [ config.deps.python.pkgs.hatchling ];
+    pythonImportsCheck = [
+      "artist"
+    ];
+  };
+
+  #paths.lockFile = "lock.${config.deps.stdenv.system}.json";
+  pip = {
+    # Setting editables.$pkg to a relative or absolute path, as a string, will
+    # link this path as an editable install to .dream2nix/editables in
+    # devShells. The root package is always installed as editable.
+    # editables.charset-normalizer = "/home/my-user/src/charset-normalizer";
+
+    requirementsList =
+      pyproject.build-system.requires
+      or []
+      ++ pyproject.project.dependencies or [];
+    flattenDependencies = true;
+
+  };
+}

flake.nix

@@ -0,0 +1,69 @@
+{
+  # This example flake.nix is pretty generic and the same for all
+  # examples, except when they define devShells or extra packages.
+  description = "Dream2nix example flake";
+
+  # We import the latest commit of dream2nix main branch and instruct nix to
+  # re-use the nixpkgs revision referenced by dream2nix.
+  # This is what we test in CI with, but you can generally refer to any
+  # recent nixpkgs commit here.
+  inputs = {
+    dream2nix.url = "github:nix-community/dream2nix";
+    nixpkgs.follows = "dream2nix/nixpkgs";
+  };
+
+  outputs = {
+    self,
+    dream2nix,
+    nixpkgs,
+  }: let
+    # A helper that helps us define the attributes below for
+    # all systems we care about.
+    eachSystem = nixpkgs.lib.genAttrs [
+      "aarch64-darwin"
+      "aarch64-linux"
+      "x86_64-darwin"
+      "x86_64-linux"
+    ];
+  in {
+    packages = eachSystem (system: {
+      # For each system, we define our default package
+      # by passing in our desired nixpkgs revision plus
+      # any dream2nix modules needed by it.
+      default = dream2nix.lib.evalModules {
+        packageSets.nixpkgs = nixpkgs.legacyPackages.${system};
+        modules = [
+          # Import our actual package definiton as a dream2nix module from ./default.nix
+          ./default.nix
+          {
+            # Aid dream2nix to find the project root. This setup should also works for mono
+            # repos. If you only have a single project, the defaults should be good enough.
+            paths.projectRoot = ./.;
+            # can be changed to ".git" or "flake.nix" to get rid of .project-root
+            paths.projectRootFile = "flake.nix";
+            paths.package = ./.;
+          }
+        ];
+      };
+    });
+    devShells = eachSystem (system: let
+      pkgs = nixpkgs.legacyPackages.${system};
+      artist = self.packages.${system}.default;
+      python = artist.config.deps.python;
+    in {
+      default = pkgs.mkShell {
+        # inherit from the dream2nix generated dev shell
+        inputsFrom = [artist.devShell];
+        packages = [
+          python.pkgs.python-lsp-server
+          python.pkgs.python-lsp-ruff
+          python.pkgs.pylsp-mypy
+          python.pkgs.ipython
+          pkgs.hatch
+          pkgs.ruff
+          pkgs.black
+        ];
+      };
+    });
+  };
+}